:. Obverse

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary

Obverse | u :. v mu lu ru |

The result of`u :. v` is the verb`u`,`` but with an assigned obverse`v` (used as the “inverse” under the conjunctions`&.` and`^:`).

For example:

       y=: _4 0 4 3j4
       rp=: <@(%: , -@%:)"0        NB. Root pairs
       rp y
    +--------+---+----+---------+
    |0j2 0j_2|0 0|2 _2|2j1 _2j_1|
    +--------+---+----+---------+

       I=: ^: _1
       rp I                        NB. No assigned obverse
    rp^:_1

       rp I rp y
    |domain error
    |     rp I rp y

       inv=: *:@{.@,@>
       inv rp y
    _4 0 4 3j4

       RP=: rp :. inv              NB. Assigned obverse in RP
       RP I RP y
    _4 0 4 3j4

       rc=: <@(,: +)@(, -)@%:"0    NB. Root companions
       rc y
    +---------+---+----+----------+
    | 0j2 0j_2|0 0|2 _2| 2j1 _2j_1|
    |0j_2  0j2|0 0|2 _2|2j_1  _2j1|
    +---------+---+----+----------+

       RC=: rc :. inv
       RC I RC y
    _4 0 4 3j4

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary